<xsl:stylesheet xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" exclude-result-prefixes="xs" version="2.0">
    <xsl:output indent="yes"/>
    <xsl:template match="/">
        <oai_dc:dc xmlns:dc="http://purl.org/dc/elements/1.1/" xmlns:oai_dc="http://www.openarchives.org/OAI/2.0/oai_dc/" xmlns:t="http://www.tei-c.org/ns/1.0" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
            <dc:title>
                <xsl:value-of select="//t:titleStmt/t:title"/>
            </dc:title>
            <dc:creator>
                <xsl:text>Born digital. DERLA Projekt und Erweiterungen</xsl:text>
            </dc:creator>
            <dc:description>
                <xsl:value-of select="//t:editorialDecl/t:p"/>
                <xsl:value-of select="//t:projectDesc/t:p"/>
            </dc:description>
            <dc:date>
                <xsl:value-of select="//t:publicationStmt/t:date/@when"/>
            </dc:date>
            <dc:language>
                <xsl:value-of select="//t:profileDesc/t:langUsage/t:language/@ident"/>
            </dc:language>
            <dc:relation>DERLA: Digitale Erinnerungslandschaft</dc:relation>
            <dc:relation>http://gams.uni-graz.at/derla</dc:relation>
            <dc:publisher>Centrum für Jüdische Studien Graz</dc:publisher>
            <dc:rights>Resource licensed under Creative Commons BY-NC 4.0</dc:rights>
            <dc:identifier>
                <xsl:value-of select="//t:idno[@type='PID']"/>
            </dc:identifier>
            
            <!-- dc:subject handles state assignment -->
            <xsl:variable name="teiPid">
                <xsl:value-of select="//t:idno[@type='PID']"/>
            </xsl:variable>
            <xsl:choose>
                <xsl:when test="contains($teiPid, 'sty')">
                    <dc:subject>Erinnerungsorte Steiermark</dc:subject>
                </xsl:when>
                <xsl:when test="contains($teiPid, 'vor')">
                    <dc:subject>Erinnerungsorte Vorarlberg</dc:subject>
                </xsl:when>
                <xsl:when test="contains($teiPid, 'car')">
                    <dc:subject>Erinnerungsorte Kärnten</dc:subject>
                </xsl:when>
                <xsl:when test="contains($teiPid, 'tir')">
                    <dc:subject>Erinnerungsorte Tirol</dc:subject>
                </xsl:when>
                <xsl:when test="contains($teiPid, 'bur')">
                    <dc:subject>Erinnerungsorte Burgenland</dc:subject>
                </xsl:when>
                <xsl:when test="contains($teiPid, 'sal')">
                    <dc:subject>Erinnerungsorte Salzburg</dc:subject>
                </xsl:when>
                <xsl:when test="contains($teiPid, 'upp')">
                    <dc:subject>Erinnerungsorte Oberösterreich</dc:subject>
                </xsl:when>
                <xsl:when test="contains($teiPid, 'low')">
                    <dc:subject>Erinnerungsorte Niederösterreich</dc:subject>
                </xsl:when>
                <xsl:when test="contains($teiPid, 'vie')">
                    <dc:subject>Erinnerungsorte Wien</dc:subject>
                </xsl:when>
            </xsl:choose>
            
            <!-- Checks if TEI represents a place of remembrance -->
            <xsl:if test="//t:div[@type='maintext']">
                <!-- types represents erinnerungsort -->
                <dc:type>Erinnerungsort</dc:type>
                <xsl:for-each select="//t:term">
                    <dc:type><xsl:value-of select="."/></dc:type>
                </xsl:for-each>
            </xsl:if>
            
            <!-- dc subject Vermittlung for material that is relevant for educational purposes in DERLA -->
            <xsl:if test="contains(//t:sourceDesc/t:p, 'Vermittlung')">
                <dc:subject>Vermittlung</dc:subject>
            </xsl:if>
            
            
            <!-- Checks if TEI represents a fixiertes Vermittlungsangebot -->
            <xsl:if test="//t:sourceDesc/t:p = 'Fixiertes Vermittlungsangebot, born digital'">
                <dc:type>Fixiertes Vermittlungsangebot</dc:type>
                <xsl:for-each select="//t:settingDesc/t:place/t:idno">
                    <dc:relation><xsl:value-of select="."/></dc:relation>        
                </xsl:for-each>
            </xsl:if>
            
            <!-- Check if dynamisches Vermittlungsangebot -->
            <xsl:if test="//t:sourceDesc/t:p = 'Dynamisches Vermittlungsangebot, born digital'">
                <dc:type>Dynamisches Vermittlungsangebot</dc:type>
            </xsl:if>
            
            <!-- dc type Anleitung if Tutorial -->
            <xsl:if test="contains(//t:sourceDesc/t:p, 'Tutorial')">
                <dc:type>Anleitung</dc:type>
            </xsl:if>
            
            <!-- Archive of Names list -->
            <xsl:if test="//t:body/t:listPerson">
                <dc:type>Personenliste</dc:type>
            </xsl:if>
            
        </oai_dc:dc>
    </xsl:template>
</xsl:stylesheet>